代码之家 › 专栏 › 技术社区 › Eric

在嵌套循环中使用变量%%f的批处理文件失败

batch-file

Eric · 技术社区 · 7 年前

set filepath=%1
for /f %%f in ('dir /ad /b %filepath%') do (
if exist "%filepath%\%%f\docs" (
for /r %filepath%\%%f\docs %%r in (*.docx) do (
echo %%f
copy %%r "%cd%\edited"
)
)
)

输出

if exist "C:\Documents\WordDocs\Data1\docs" (for /R C:\Documents\WordDocs\%f\docs %r in (*.docx) do ( 
echo Data1
copy %r "C:\Users\admin\Desktop\Test"
) ) )

2 回复 | 直到 7 年前

aschipfl 7 年前

这个 for command (如 if command )比其他命令更早解析。此时, 对于 变量引用,如 %%f for /R 无法使用包含 对于 变量引用类 . 对于的选项字符串也是如此 for /F . 您也不能使用 delayed expanded variable 而不是 %%f

手边的脚本最简单的解决方法是使用 pushd "%filepath%\%%f\docs" 用于/R 循环和 popd 使用其默认根,即当前工作目录,该目录刚刚由 ; 前一个恢复时间为 . 以下是我的意思:

set "filepath=%~1"
for /F %%f in ('dir /A:D /B "%filepath%"') do (
    if exist "%filepath%\%%f\docs" (
        pushd "%filepath%\%%f\docs"
        for /R %%r in ("*.docx") do (
            echo/%%f
            copy "%%~r" "%cd%\edited"
        )
        popd
    )
)

用于/R 循环到一个子例程中,通过 call command 并将根路径作为 argument

set "filepath=%~1"
for /F %%f in ('dir /A:D /B "%filepath%"') do (
    if exist "%filepath%\%%f\docs" (
        call :SUB "%filepath%\%%f\docs"
    )
)
goto :EOF

:SUB
for /R "%~1" %%r in ("*.docx") do (
    echo/%%f
    copy "%%~r" "%cd%\edited"
)
goto :EOF

参考此帖子: How does the Windows Command Interpreter (CMD.EXE) parse scripts?

Compo 7 年前

此版本不使用 For /R

For /F "Delims=" %%A In ('Dir/B/AD-L "%~1"') Do If Exist "%~1\%%A\docs\" (
    For /F "Delims=" %%B In ('Dir/B/S/A-D-L "%~1\%%A\docs\*.docx"'
    ) Do Echo=Copy "%%~B" "%CD%\edited")
Pause

Echo= 在第3行,如果您对cmd窗口中的输出满意, 记住取消编辑目标路径

推荐文章

SxDiablo · 使用管理员权限从“C”中批量删除(del/f“C:\Users\USER\Desktop\New folder\File.rar”)“拒绝访问”。为什么?

1 年前

late1 · 批处理文件未执行命令

2 年前

Ali EXE · 如何根据bat中命令的输出设置变量?

2 年前

Iliyas Momin · 如何在文本文件中获得python脚本输出,而不覆盖当前的一个文本文件

2 年前

fallbeilspiel · 如何获取使用批处理文件打开的程序的名称?

2 年前

Laureano Oliva · 如何将链接用作参数%1批处理函数?

2 年前

Jung hoon Park · 如何使用diskpart指令作为批处理文件断开外部硬盘?

2 年前

absoluteidiot · 是否可以在批处理脚本中使用通配符来获取路径下的所有目录,然后使用相关名称创建文件

2 年前

F35H · 涉及二次使用cd的错误。。在C代码中

2 年前

WarDaddy _Justin · 想经营一家公司。在不同机器上安装多个程序的bat脚本

2 年前