代码之家 › 专栏 › 技术社区 › cala

从GoogleFinance获取特定日期的汇率

google-finance google-sheets-formula currency google-sheets

cala · 技术社区 · 7 年前

我无法在特定日期停止googlefinance功能,以使用“该”特定汇率将货币从英镑转换为欧元。

这是我的公式: =Finance!B4*GOOGLEFINANCE("CURRENCY:GBPEUR","price",date(2017,15,11))

以下是错误: When evaluating GOOGLEFINANCE, the query for the symbol: 'CURRENCY:GBPEUR' returned no data.

我已经研究了其他解决方案,但没有一个是有效的。我实际上已经添加了 “日期” 和 “价格” 从其他解到我的公式。像这样:- Solution 1

7 回复 | 直到 5 年前

user6655984 user6655984 7 年前

首先 date(2017,15,11) 表示一年中15个月的第11天,因此您需要交换月份和日期。

其次,历史数据查询,例如

=GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15))

返回包含列和标题的表。

Date                Close
11/15/2017 23:58:00 1.1163

从你使用这个公式的方式来看,我知道你只需要汇率。将函数包装在 index(..., 2, 2) 获取第二行中的第二个单元格。

=index(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", date(2017,11,15)), 2, 2)

Niloct 3 年前

为了确保大家都知道 , 运算符在今天的谷歌表单中没有使用,因此避免解析器错误的正确表达式是(在您的情况下):

=index(GOOGLEFINANCE("CURRENCY:GBPEUR"; "price"; date(2017;11;15)); 2; 2)

Gaurav Jeswani 5 年前

这是我对这个公式的理解。

哪里 B3 应为有效日期。

=index(GOOGLEFINANCE("CURRENCY:USDCNY", "price", B3), 2, 2)

附言我不知道为什么,但当我指定2018年12月15日时,公式显示了一个错误。所有其他日期均正确。

Procrastinator natan barron 3 年前

在Google Sheets中,我使用分号这样做:

=index(googlefinance("currency:USDNOK";"price";G11);2;2)

G11是我的单元格,包含日期。它似乎为我做了这项工作。我在G11中用今天的日期进行了测试,得到了与今天汇率的简化版本相同的结果:

=googlefinance("currency:USDNOK")

player0 5 年前

您的问题是(曾经)您试图强制提供不存在的第15个月的数据。语法 DATE 是:

=DATE(YEAR(), MONTH(), DAY())

因此,完整公式应为:

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATE(2017, 11, 15)), 2, 2)

备选方案包括:

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", "15/11/2014"), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", DATEVALUE("15/11/2014")), 2, 2)

=Finance!B4*INDEX(GOOGLEFINANCE("CURRENCY:GBPEUR", "price", A1), 2, 2)

其中A1包含有效日期

Vendrel 3 年前

:D什么都不起作用。无论我在单元格中插入什么日期或地址,无论我声明什么货币对,无论我在单元格中插入什么价格或地址,无论是否有索引,它都返回“分析错误”。我喜欢这种情况。

SBM 4 年前

2018年12月15日是周日,因此出现了错误。您可以添加-2或+2,因为错误也会在周六弹出。我更喜欢-2