k个连续整数约束

也许使用正则约束(Comet中的自动机)将是最好的方法。

然而,在MiniZinc中有一个简单的解决方案,它使用了大量的具体化。至少可以将其翻译成彗星(我认为古罗比不支持实体化)。

决策变量(序列)在数组“x”中。它还使用一个辅助数组(“starts”),其中包含每个序列的起始位置;这使得对“x”中的序列进行推理变得更容易。序列的数量以“z”为单位(例如,对于优化问题)。

根据x的大小和其他约束,可能会添加更多(冗余)约束,限制可以有多少个序列等。不过,这里没有这样做。

这是模型: http://www.hakank.org/minizinc/k_consecutive_integers.mzn

它也显示在下面。

int: n;
int: k;

% number of consecutive integers for each integer 1..k
array[1..k] of int: c;

% decision variables
array[1..n] of var 1..k: x;

% starts[i] = 1 ->  x[i] starts a new sequence
% starts[i] = 0 ->  x[i] is in a sequence
array[1..n] of var 0..k: starts;
% sum of sequences
var 1..n: z = sum([bool2int(starts[i] > 0) | i in 1..n]);

solve :: int_search(x, first_fail, indomain_min, complete) satisfy;

constraint
   forall(a in 1..n, b in 1..k) (
      (starts[a] = b ) -> 
         (
             forall(d in 0..c[b]-1) (x[a+d] = b )
             /\
             forall(d in 1..c[b]-1) (starts[a+d] = 0 )
             /\
             (if a > 1 then x[a-1] != b else true endif)    % before 
             /\
             (if a <= n-c[b] then x[a+c[b]] != b else true endif) % after
         )
  )
  /\
  % more on starts
  starts[1] > 0 /\
  forall(i in 2..n) (
     starts[i] > 0 <-> ( x[i]!=x[i-1] )
  )
  /\
  forall(i in 1..n) (
     starts[i] > 0 -> x[i] = starts[i]
  )
;

output [ 
     "z     : " ++ show(z) ++ "\n" ++
     "starts: " ++ show(starts) ++ "\n" ++
     "x     : " ++ show(x)  ++ "\n"
];


%
% data
%

%% From the question above:
%% It's a unique solution.
n = 13;
k = 2;
c = [3,2];