任务表单中的日期显示格式,除非日期不存在

我会用一个单独的程序来检查表格上的任何日期。
如果输入了无效的日期,也会将控件涂成红色。
将日期格式化为 dd-mmm-yyyy 当月份以完整格式(ish)书写时,更容易发现格式错误的日期。

Public Sub FormatDate(ctrl As Control)

    Dim dDate As Date
    Dim IsDate As Boolean

    On Error GoTo ERR_HANDLE

    If Replace(ctrl.Value, " ", "") <> "" Then
        On Error Resume Next
            dDate = CDate(ctrl.Value)
            IsDate = (Err.Number = 0)
            On Error GoTo 0
        On Error GoTo ERR_HANDLE

        If IsDate Then
            ctrl.Value = Format(ctrl.Value, "dd-mmm-yyyy")
            ctrl.BackColor = RGB(255, 255, 255)
        Else
            ctrl.BackColor = RGB(255, 0, 0)
        End If
    End If

EXIT_PROC:
        On Error GoTo 0
        Exit Sub

ERR_HANDLE:
        'Error Handling routines.
        'DisplayError Err.Number, Err.Description, "mdl_FormatDate.FormatDate()"
        Resume EXIT_PROC

End Sub  

然后在 AfterUpdate 控件事件:

Private Sub txtDate_AfterUpdate()

    On Error GoTo ERR_HANDLE

    With Me
        FormatDate .txtDate
    End With

EXIT_PROC:
        On Error GoTo 0
        Exit Sub

ERR_HANDLE:
        'Error Handling routines.
        'DisplayError Err.Number, Err.Description, "Data_Entry_Form.txtDate_AfterUpdate()"
        Resume EXIT_PROC

End Sub

您可以执行以下操作,但您的用户应该知道以正确的(英国)格式输入日期:

    sDate = Format(CDate(sDate.Text), "dd/mm/yyyy")
    EDate = Format(CDate(EDate.Text), "dd/mm/yyyy")